ReHLDS/HLDS Unreal Stuck Detector

[karaulov]

Очередной мой новый античит!!

Плагин обнаруживает и мгновенно предупреждает всех что игрок использует функцию из чит программы под названием AIR STUCK.

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <engine>
#include <reapi>

new const Plugin_sName[] = "Unreal Stuck Detector";
new const Plugin_sVersion[] = "1.0.7";
new const Plugin_sAuthor[] = "Karaulov";

new Float:cmd_time[33] = {0.0,...};

new cmd_warns[33] = {0,...};

new Float:cmd_start_time = 0.0;

public plugin_init()
{
    register_plugin(Plugin_sName, Plugin_sVersion, Plugin_sAuthor);
    register_cvar("unreal_stuck_detect", Plugin_sVersion, FCVAR_SERVER | FCVAR_SPONLY);
    register_forward(FM_CmdStart, "pfw_CmdStart")
    register_clcmd("hello_world","hello_world");
    cmd_start_time = get_gametime();
}

public client_putinserver(id)
{
    cmd_warns[id] = 0;
    cmd_time[id] = get_gametime() + 7.5;
    if (task_exists(id))
        remove_task(id);
    if (task_exists(id + 100))
        remove_task(id + 100);
    if (!is_user_bot(id))
    {
        set_task(0.2,"send_hello_world", id, _, _, "b");
        set_task(10.0,"reset_warns", id + 100, _, _, "b");
    }
}

public client_disconnected(id)
{
    cmd_warns[id] = 0;
    if (task_exists(id))
        remove_task(id);
    if (task_exists(id + 100))
        remove_task(id + 100);
}

public reset_warns(id)
{
    cmd_warns[id - 100] = 0;
}

public send_hello_world(id)
{
    if (is_user_alive(id) && get_gametime() - cmd_time[id] > 0.2)
    {
        client_cmd(id,"hello_world");
    }
}

public hello_world(id)
{
    check_user_for_somethingbad(id);
    return PLUGIN_HANDLED;
}

public pfw_CmdStart(id, pUC, seed)
{
    if (is_user_bot(id))
    {
        return FMRES_IGNORED
    }
    cmd_time[id] = get_gametime();
   
    new uc = get_uc(pUC,UC_Msec);
    if (uc == 0 && get_gametime() - cmd_start_time > 20.0 )
    {
        new username[33];
        get_user_name(id,username,charsmax(username));
        client_print_color(0,print_team_red, "^4[STUCK DETECTOR #2]^3: Игрок^1 %s^3 использует ^1AIR STUCK HACK^3!",username);
        log_amx("[STUCK DETECTOR #2]: Игрок %s использует AIR STUCK HACK!",username);
        //server_cmd("amx_ban 10080 #%d ^"Запрещено играть с AIR STUCK HACK! #2^"",get_user_userid(id));
    }
   
    return FMRES_IGNORED
}

public client_command(id)
{
    check_user_for_somethingbad(id);
}

public check_user_for_somethingbad(id)
{
    if (is_user_alive(id) && get_gametime() - cmd_time[id] > 0.5 && get_gametime() - cmd_start_time > 20.0 )
    {
        cmd_warns[id]++;
        if (cmd_warns[id] == 5)
        {
            new username[33];
            get_user_name(id,username,charsmax(username));
            client_print_color(0,print_team_red, "^4[STUCK DETECTOR]^3: Игрок^1 %s^3 использует ^1AIR STUCK HACK^3!",username);
            log_amx("[STUCK DETECTOR]: Игрок %s использует AIR STUCK HACK!",username);
            //server_cmd("amx_ban 10080 #%d ^"Запрещено играть с AIR STUCK HACK!^"",get_user_userid(id));
        }
    }
}

 

[c666b]

karaulov, что-то в гугле одна лишь CS:GO с таким читом

 

[Justick]

Что это за чит вообще?

 

[karaulov]

Функция из читов позволяющая зависать в воздухе, есть у многих приват читов

 

[karaulov]

Обновление 1.0.2
Исправление ложных срабатываний

 

[karaulov]

Обновление 1.0.3
Исправление ложных срабатываний на FPS BOOSTER

 

[asla4ok]

пора уже полноценный античит написать, а то 3 плагин ставлю от тебя)

 

[CCleaner]

Функция из читов позволяющая зависать в воздухе, есть у многих приват читов

Я не мог понять, что такое блок.
Можете ли вы показать нам ссылку?

 

[karaulov]

Может изредка выдавать ложные , но если очень часто на игроки срабатывает он точно чит, скоро выпущу обновление

 

[Noob with cheats!]

Люблю такой чит. Игроки с ним хотят показать "чудеса" из-за "багов", но получают баны.

 

[karaulov]

Проверьте 1.0.4 по идее ложных не будет но я не проверял с читом.

 

[s1ngle71rus]

Проверьте 1.0.4 по идее ложных не будет но я не проверял с читом.

у меня боты в бан отлетают можно исправить?)

 

[karaulov]

Ахахаха) читеры, да можно проверку добавить нада)))

Обновил 1.0.5

 

[karaulov]

1.0.6 исправлена очень плохая ошибка

 

[karaulov]

1.0.7 client_connect->client_putinserver, и задержка 20 секунд после смены карты.

 

[StaryiWoW]

1.0.7 client_connect->client_putinserver, и задержка 20 секунд после смены карты.

А можете в двух словах описать за что банит в первом случае и во втором? (DETECTOR и DETECTOR№2)

 

[karaulov]

1 alternative hack air stuck
2 hpp hack air stuck

 

[StaryiWoW]

1 alternative hack air stuck
2 hpp hack air stuck

а это 100% обнаружения? Или вероятности ошибки есть?

 

[karaulov]

StaryiWoW, есть вероятность ошибки

 

[StaryiWoW]

StaryiWoW, есть вероятность ошибки

А вот это интересно. С чем связаны? Я этим вопросом задался после того, как поставил для интереса ваш плагин. Обнаружилось, что HPP стоит у 2ух нубов, у которых стата и уровень игры... Ну скажем так, ниже среднего
Ну это не считая того, что нашлось и у других.